20.3.1. one_for_one¶

One for one（1対1）は直感的な再起動戦略です。 基本的に、スーパバイザがたくさんのワーカを監視していて、そのうちの1つが失敗したとき場合、その1つだけが再起動されるべきという意味です。 one_for_one は、監視されているプロセスが各々独立していて、お互い関係していない場合はいつでも、あるいはプロセスが再起動して状態が消えてしまっても、隣のプロセスに影響を与えない場合に使われるべきです。

20.3.2. one_for_all¶

One for all（1対全部）は三銃士とは関係ありません。 これは、1つのスーパバイザ下にあるすべてのプロセスが、正常に動作するためにお互いに強く依存している場合にはいつでも使われます。 たとえば、前の章 Rage Against The Finite-State Machines で実装した取引システムの一番上にスーパバイザを追加することに決めたとしましょう。 このとき、取引をしている2人のユーザのFSMのうち1つがクラッシュした場合に、その1つだけを再起動したのでは意味がありません。なぜなら、彼らの状態が同期から外れてしまうからです。 両方共同時に再起動するのが健全な選択であり、 one_for_all はこのようなときのための戦略です。

20.3.3. rest_for_one¶

この戦略はより特別な状況のためのものです。 チェーン状態に依存しているプロセスを起動する場合はいつでも（AをBが起動し、BがCを起動し、CがDを起動する、など）、 rest_for_one が使えます。 似た依存関係を盛ったサービスの場合にも便利です。（たとえば、Xは単独で動作しているが、YはXに依存していて、ZはXとYの両方に依存している） rest_for_one の再起動戦略は、基本的には、プロセスが死んだ時に、そのプロセスよりもあとに起動した（依存した）プロセスは再起動するけれど、それ以外はそのまま、というものです。

20.3.4. simple_one_for_one¶

simple_one_for_one の再起動戦略は、最も複雑なものです。 詳細についてはこれを使うようになるまでは見ませんが、基本的にはある種の子プロセスがあって、それらが静的に起動させるというよりも、動的にスーパバイザに追加したい場合に使われます。

違う言い方をすれば、 simple_one_for_one スーパバイザはただそこにいて、1種類の子供しか生成できないということがわかっています。 新しい子プロセスが欲しければ、そのスーパバイザに頼んで生成してもらいます。 これは理論的には通常の one_for_one スーパバイザにも出来ますが、 simple_one_for_one を使う実用的な利点があるのです。

20.3.5. 再起動制限¶

RestartStrategy タプルに関して最後に MaxRestart と MaxTime という変数の組について触れます。 基本的な考えとしては、 MaxTime (秒)以内に MaxRestart 回再起動がかかったら、スーパーバイザは再起動を断念して、自身をシャットダウンします。(なんと残念なんでしょう) 幸いにも、そのスーパーバイザのスーパーバイザが、まだその子プロセスをすべて再起動させる可能性はあります。

20.4.1. ChildId¶

ChildId はスーパーバイザの内部で使用される単なる内部的な名前です。 開発時に利用することは少ないですが、デバッグでの利用や、実際にあるスーパーバイザのすべての子プロセスのリストを取得するとき決めたときに利用できます。 どのような項もIDとして利用可能です。

20.4.2. StartFunc¶

StartFunc はスーパーバイザの起動方法を伝えるためのタプルです。 これは、これまで何度か使ってきた、通常の {M, F, A} の形式です。 ここで起動関数は、OTP準拠で、実行時はその呼び出し元とリンクしているということが非常に重要なので、留意しておいて下さい。(ヒント: gen_*:start_link() は常に独自モジュール内でラップされています)

20.4.3. Restart¶

Restart はスーパーバイザに特定の子プロセスが死んだときにどのような処理を行うかを伝えます。 これは3つの値を取ります:

• permanent (永続的)
• temporary (一時的)
• transient (暫定的)

永続的プロセスは、それがどんなプロセスであろうと、常に再起動されるべきです。 私たちが先のアプリケーションで実装したスーパーバイザはこの戦略のみを使っています。 この戦略は通常ノード上で致命的な、長期間稼働するプロセス(またはサービス)に用いられます。

一方で、一時的なプロセスは、決して再起動されるべきでないプロセスです。 これらのプロセスは稼働期間が短く失敗することが前提のもので、依存するコードが少ないワーカのためにあります。

暫定的プロセスはその中間にあります。 これは、正常に終了するまでは稼働し、その後は再起動されません。 一方で、異常終了した場合(終了の原因が正常の場合以外すべて)は、再帰動作されます。 この再起動方法は、タスクを完了させる必要があるけれども、それが終わったら必要なくなるワーカに対してしばしば使われます。

1つのスーパーバイザ下にこれら3種類のうちどれを使ったプロセスでも子プロセスとして持つことが出来ます。 これは再起動戦略にも影響します。つまり one_for_all は、ある一時的プロセスが死んだ時には作用しませんが、同じスーパーバイザ下で先に永続的プロセスが死んだ場合には、その一時的プロセスは再起動されるでしょう。

20.4.4. Shutdown¶

本章の最初のほうで、スーパーバイザの助けを借りてアプリケーション全体を終了させることができると言いました。 この節はその方法について説明します。 最上位のスーパーバイザが終了するように命じられたとき、スーパーバイザは exit(ChildId, shutdown) を各Pidに対して呼び出します。 その子プロセスがワーカで終了を捕捉したら、自身の終了関数を呼びます。 または、単純に死にます。 スーパーバイザがshutdownシグナルを受け取ったとき、子プロセスに同様にメッセージを転送します。

したがって、子プロセスの仕様にある Shutdown という値は、終了の期限を設定するために使われます。 あるワーカでは、適切にファイルを閉じたり、サービスに退出するなどの事をしなければならないと知っているでしょう。 このような場合、ミリ秒単位なのか、あるいは辛抱強ければ無制限なのか、いずれにせよ特定の制限時間を設定したいときもあるでしょう。 もし時間が経って何も起きなければ、プロセスは exit(Pid, kill) が呼び出されて強制終了されます。 子プロセスに関して特に気にすることがなく、子プロセスが特にどんな結果も出さず、特に時間制限も必要なければ、 brutal_kill も使えるでしょう。 brutal_kill は、子プロセスが exit(Pid, Kill) で殺されるように、子プロセスを強制終了します。これは捕捉はできず、即座に行われます。

Shutdown の値を適切に選ぶことは、ときどき複雑または扱いにくいものです。 チェーン構造でつながったスーパーバイザの Shutdown の値が、たとえばそれぞれ 5000 -> 2000 -> 5000 -> 5000 だった場合、最後の2つは強制的に殺されることが起こりえます。なぜなら、2つ目のほうが短い切断時間だからです。 これは完全にアプリケーションに依存した値で、この点に関してはほとんどヒントはありません。

20.4.5. Type¶

Typeは単純にスーパーバイザに子供がワーカなのかスーパーバイザなのかを知らせます。 これはアプリケーションをより進んだOTPの機能で更新する場合に重要ですが、当面は気にする必要はありません―本当のことを言っていますし、すべて問題ありません。 スーパーバイザを信頼してください!

20.4.6. Modules¶

Modules は1つの要素、子供のビヘイビアに使われるコールバックモジュール名のリストです。 例外は、事前にコールバックモジュールを知らない場合です。(イベントマネージャ内のイベントハンドラとか) この場合、 Modules の値は動的で、OTPシステム全体がリリースのような、より応用的な機能を使うときに誰に聞いたら良いかわかるようにすべきです。

やったね、これでスーパーバイザプロセスを起動するのに必要な基本的な知識を得ることができました。 休憩をして、すべてを消化しましょう。あるいは、先に進んでもっと学びましょう!

20.5.1. Musicians¶

まずできることは、個々のバンドメンバを書くことです。 私たちのユースケースでは、musiciansモジュールは gen_server を実装します。 各ミュージシャンはパラメータとして楽器と演奏レベルを持ちます。(これで、ドラマーは下手くそな一方で、他のメンバーは問題ないと言えます。) いったんミュージシャンが一人生成されたら、彼は演奏を始めます。 また、必要があれば演奏を止めるオプションもあります。 このようなモジュールとインターフェースができました:

-module(musicians).
-behaviour(gen_server).

-export([start_link/2, stop/1]).
-export([init/1, handle_call/3, handle_cast/2,
         handle_info/2, code_change/3, terminate/2]).

-record(state, {name="", role, skill=good}).
-define(DELAY, 750).

start_link(Role, Skill) ->
    gen_server:start_link({local, Role}, ?MODULE, [Role, Skill], []).

stop(Role) -> gen_server:call(Role, stop).

ミュージシャンが演奏する標準的な時間として使うために ?DELAY マクロを定義しました。 レコードの定義からわかるように、それぞれに名前を与えなければいけません:

init([Role, Skill]) ->
    %% To know when the parent shuts down
    process_flag(trap_exit, true),
    %% sets a seed for random number generation for the life of the process
    %% uses the current time to do it. Unique value guaranteed by now()
    random:seed(now()),
    TimeToPlay = random:uniform(3000),
    Name = pick_name(),
    StrRole = atom_to_list(Role),
    io:format("Musician ~s, playing the ~s entered the room~n",
              [Name, StrRole]),
    {ok, #state{name=Name, role=StrRole, skill=Skill}, TimeToPlay}.

init/1 関数では2つのことが行われています。 まず、終了を捕捉しています。 汎用サーバの章での terminate/2 の説明を思い出せば、 terminate/2 がサーバの親がその子供終了させるときに呼ばれるようにしたいのであれば、これをする必要があるとわかります。 init/1 関数の残りの部分はランダムシードを設定して(これで各プロセスが異なるランダム値を持つことができます)、それから自身にランダムな名前を生成します。 名前を生成する関数は次のようになります:

%% Yes, the names are based off the magic school bus characters'
%% 10 names!
pick_name() ->
    %% the seed must be set for the random functions. Use within the
    %% process that started with init/1
    lists:nth(random:uniform(10), firstnames())
    ++ " " ++
    lists:nth(random:uniform(10), lastnames()).

firstnames() ->
    ["Valerie", "Arnold", "Carlos", "Dorothy", "Keesha",
     "Phoebe", "Ralphie", "Tim", "Wanda", "Janet"].

lastnames() ->
    ["Frizzle", "Perlstein", "Ramon", "Ann", "Franklin",
     "Terese", "Tennelli", "Jamal", "Li", "Perlstein"].

いいですね! 実装に進みましょう。 このモジュールは handle_call と handle_cast については非常に平凡なものになります:

handle_call(stop, _From, S=#state{}) ->
    {stop, normal, ok, S};
handle_call(_Message, _From, S) ->
    {noreply, S, ?DELAY}.

handle_cast(_Message, S) ->
    {noreply, S, ?DELAY}.

唯一持てる関数呼び出しはミュージシャンサーバを止めるものだけです。これには私たちも大賛成です。 私たちが予期せぬメッセージを受け取った場合、それには返信せず、呼び出し元はクラッシュします。 私たちの問題ではありません。 {noreply, S, ?DELAY} タプルでタイムアウトを設定します。これは次に見るような1つの単純な理由のためです:

handle_info(timeout, S = #state{name=N, skill=good}) ->
    io:format("~s produced sound!~n",[N]),
    {noreply, S, ?DELAY};
handle_info(timeout, S = #state{name=N, skill=bad}) ->
    case random:uniform(5) of
        1 ->
            io:format("~s played a false note. Uh oh~n",[N]),
            {stop, bad_note, S};
        _ ->
            io:format("~s produced sound!~n",[N]),
            {noreply, S, ?DELAY}
    end;
handle_info(_Message, S) ->
    {noreply, S, ?DELAY}.

サーバがタイムアウトするたびに、私たちのミュージシャンは楽譜を演奏します。 もしメンバーの調子が良ければ、すべては順調です。 もし調子が悪ければ、5回のチャンスのうち1回を使って、悪い演奏をし、その結果ミュージシャンサーバはクラッシュします。 再度、無制限の関数呼び出しの最後に ?DELAY タイムアウトを設定します。

そのあと、 ‘gen_server’ビヘイビアで必要なので、空の code_change/3 コードバックを追加します:

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

そしてterminate関数も設定できます：

terminate(normal, S) ->
    io:format("~s left the room (~s)~n",[S#state.name, S#state.role]);
terminate(bad_note, S) ->
    io:format("~s sucks! kicked that member out of the band! (~s)~n",
              [S#state.name, S#state.role]);
terminate(shutdown, S) ->
    io:format("The manager is mad and fired the whole band! "
              "~s just got back to playing in the subway~n",
              [S#state.name]);
terminate(_Reason, S) ->
    io:format("~s has been kicked out (~s)~n", [S#state.name, S#state.role]).

ここで多くの異なるメッセージが出てきました。 もし私たちが正常な理由で終了したら、それは私たちが stop/1 関数を呼び出して、自分の自由意志で退出したミュージシャンの名前を表示します。 bad_note メッセージの場合は、ミュージシャンはクラッシュして、私たちは「マネージャー（すぐ後ほどに追加するスーパバイザのこと）が彼をゲームから蹴りだしたせいだ」と言うでしょう。 それから、スーパバイザからやってくる終了メッセージもあります。 このメッセージを受け取ったときは、スーパバイザがすべての子プロセスを殺すと決めた場合、あるいは私たちの場合でいえば、すべてのミュージシャンを解雇した場合となります。 その後、それ以外の場合の汎用的なエラーメッセージを追加します。

次に、musicianモジュールの簡単なユースケースを示します：

1> c(musicians).
{ok,musicians}
2> musicians:start_link(bass, bad).
Musician Ralphie Franklin, playing the bass entered the room
{ok,<0.615.0>}
Ralphie Franklin produced sound!
Ralphie Franklin produced sound!
Ralphie Franklin played a false note. Uh oh
Ralphie Franklin sucks! kicked that member out of the band! (bass)
3>
=ERROR REPORT==== 6-Mar-2011::03:22:14 ===
** Generic server bass terminating
** Last message in was timeout
** When Server state == {state,"Ralphie Franklin","bass",bad}
** Reason for termination ==
** bad_note
** exception error: bad_note

Ralphieが演奏をし、悪演奏でクラッシュしました。やったね。 いいミュージシャンで同じ事をする場合には、すべての演奏を止めるために musicians:stop(instrument) 関数を呼び出す必要があります。

20.5.2. Band Supervisor¶

ようやくスーパーバイザを扱えます。 これから作るスーパーバイザには3種類あります。おおらかなもの（lenient）、怒りっぽいもの（angry）、完全な間抜け（jerk）の3つです。 これら3つの違いは、まずおおらかなスーパーバイザは、それでも不愉快なやつではあるけれども、演奏を失敗したバンドのメンバーを彼がうんざりして、バンドを諦めたときに1人解雇します。（ one_for_one ） 一方で、怒りっぽいスーパーバイザは、間違えるごとにバンドメンバーのうち何人かを解雇し（ rest_for_one ）、おおらかなスーパーバイザよりも諦めるまでの時間が短いです。 間抜けなスーパーバイザは、先ほどの2人よりも諦める頻度は低いものの、誰かが間違えるとごとにバンド全員を解雇します。

-module(band_supervisor).
-behaviour(supervisor).

-export([start_link/1]).
-export([init/1]).

start_link(Type) ->
    supervisor:start_link({local,?MODULE}, ?MODULE, Type).

%% The band supervisor will allow its band members to make a few
%% mistakes before shutting down all operations, based on what
%% mood he's in. A lenient supervisor will tolerate more mistakes
%% than an angry supervisor, who'll tolerate more than a
%% complete jerk supervisor
init(lenient) ->
    init({one_for_one, 3, 60});
init(angry) ->
    init({rest_for_one, 2, 60});
init(jerk) ->
    init({one_for_all, 1, 60});

initの定義はまだ終わりではありませんが、ここまでの定義で私たちがほしい個々のスーパーバイザの雰囲気を設定することができました。 おおらかなものは、1つのミュージシャンを再起動させるだけで、60病間で4つのミスをした時に失敗となります。 おこりっぽいものは、2つのミスしか認めず、間抜けなものは非常に厳しい基準を持っています！

では、init関数の続きの実装を終えて、バンドを始動させる関数などの実際の実装を始めましょう：

init({RestartStrategy, MaxRestart, MaxTime}) ->
    {ok, {{RestartStrategy, MaxRestart, MaxTime},
         [{singer,
           {musicians, start_link, [singer, good]},
           permanent, 1000, worker, [musicians]},
          {bass,
           {musicians, start_link, [bass, good]},
           temporary, 1000, worker, [musicians]},
          {drum,
           {musicians, start_link, [drum, bad]},
           transient, 1000, worker, [musicians]},
          {keytar,
           {musicians, start_link, [keytar, good]},
           transient, 1000, worker, [musicians]}
          ]}}.

ご覧のとおり、3人の良いミュージシャンである、ボーカル、ベーシスト、ショルダーキーボーディストがいます。 ドラマーが困り者なのです。（彼があなたを不愉快にさせてしまうのです） ミュージシャンは異なる Restart を持っています。（ permanent, transient, temporary のいずれか）ですので、自分の意志で退出したとしても、バンドはボーカルなしには決して演奏できませんが、ベーシストなしでは依然として良い演奏をすることもできます。なぜなら、気さくに言えば、誰がベーシストに拍手を送るでしょうか。

これで、機能的な band_supervisor モジュールができました。試してみましょう：

3> c(band_supervisor).
{ok,band_supervisor}
4> band_supervisor:start_link(lenient).
Musician Carlos Terese, playing the singer entered the room
Musician Janet Terese, playing the bass entered the room
Musician Keesha Ramon, playing the drum entered the room
Musician Janet Ramon, playing the keytar entered the room
{ok,<0.623.0>}
Carlos Terese produced sound!
Janet Terese produced sound!
Keesha Ramon produced sound!
Janet Ramon produced sound!
Carlos Terese produced sound!
Keesha Ramon played a false note. Uh oh
Keesha Ramon sucks! kicked that member out of the band! (drum)
... <snip> ...
Musician Arnold Tennelli, playing the drum entered the room
Arnold Tennelli produced sound!
Carlos Terese produced sound!
Janet Terese produced sound!
Janet Ramon produced sound!
Arnold Tennelli played a false note. Uh oh
Arnold Tennelli sucks! kicked that member out of the band! (drum)
... <snip> ...
Musician Carlos Frizzle, playing the drum entered the room
... <snip for a few more firings> ...
Janet Jamal played a false note. Uh oh
Janet Jamal sucks! kicked that member out of the band! (drum)
The manager is mad and fired the whole band! Janet Ramon just got back to playing in the subway
The manager is mad and fired the whole band! Janet Terese just got back to playing in the subway
The manager is mad and fired the whole band! Carlos Terese just got back to playing in the subway
** exception error: shutdown

魔法のようです！ ドラマーだけが解雇され、しばらくしてほかのメンバーも解雇されましたね！ そして、地下鉄（イギリスの方ならチューブですね）のホームへ行ってしまいました！

他のスーパバイザも試して見ることもできます。そしてそれらは同じ結果になるでしょう。 唯一の違いは再起動戦略です：

5> band_supervisor:start_link(angry).
Musician Dorothy Frizzle, playing the singer entered the room
Musician Arnold Li, playing the bass entered the room
Musician Ralphie Perlstein, playing the drum entered the room
Musician Carlos Perlstein, playing the keytar entered the room
... <snip> ...
Ralphie Perlstein sucks! kicked that member out of the band! (drum)
...
The manager is mad and fired the whole band! Carlos Perlstein just got back to playing in the subway

おこりっぽいものは、ドラマーがミスしたときにドラマーとショルダーキーボーディストが解雇されました。 間抜けなもののビヘイビアでは比較するものはなにもありません：

6> band_supervisor:start_link(jerk).
Musician Dorothy Franklin, playing the singer entered the room
Musician Wanda Tennelli, playing the bass entered the room
Musician Tim Perlstein, playing the drum entered the room
Musician Dorothy Frizzle, playing the keytar entered the room
... <snip> ...
Tim Perlstein played a false note. Uh oh
Tim Perlstein sucks! kicked that member out of the band! (drum)
The manager is mad and fired the whole band! Dorothy Franklin just got back to playing in the subway
The manager is mad and fired the whole band! Wanda Tennelli just got back to playing in the subway
The manager is mad and fired the whole band! Dorothy Frizzle just got back to playing in the subway

動的でない再起動戦略はこれがほぼすべてです。